*** Tobit, Selection and Treatment Effects

set memory 30m
set more off

log using tobit_cnreg_intreg.log, replace

** Tobit Models

use http://www.stata-press.com/data/r8/auto, clear

generate wgt = weight/1000
regress mpg wgt

replace mpg = 17 if mpg <= 17
* this replacement is not needed, though.

tobit mpg wgt, ll nolog
* ll (lower limit), ul (upper limit)
tobit mpg wgt, ul(24) nolog
* ul (upper limit 24 is imposed)

tobit mpg wgt, ll (17) ul(24) nolog

** Tobit Models and marginal effects

use http://fmwww.bc.edu/ec-p/data/wooldridge/MROZ, clear

regress hours nwifeinc educ exper expersq age kidslt6 kidsge6

tobit hours nwifeinc educ exper expersq age kidslt6 kidsge6, ll(0) nolog

* -- fixup for expersq : take square of mean rather than mean of square per JMW
summ exper,meanonly
local exp2=r(mean)^2
mfx compute, at(mean expersq=`exp2') predict(ystar(0,.))

* -- marginal effects conditional on positive hours
mfx compute, at(mean expersq=`exp2') predict(e(0,.))
* e(a,b) gives the conditioanl expectation given a < Xb < b.


*** Panel RE Tobit (xttobit)

use http://www.stata-press.com/data/r8/nlswork, clear
xttobit ln_wage union age grade not_smsa south occ_code, i(id) ul(1.9) tobit nolog
*quadchk


** Censored regression CNREG (each can be censored at a different point)

use http://www.stata-press.com/data/r8/news, clear

generate cnsrd = 0
replace cnsrd = -1 if before82
replace date = mdy(1,1,1982) if before82
replace cnsrd = 1 if date>= .
replace date = mdy(1,1,1991) if date >= .
list date cnsrd in 1/12

cnreg date lncltn famown, censored(cnsrd) nolog

** Intreg (interval regression; even point data; needs depvar1 depvar2)
* point   		a   a
* interval		a   b
* left censored 	.   b
* right censored 	a   .

use http://www.stata-press.com/data/r8/womenwage, clear

tab wagecat
by wagecat: keep if _n == 1
generate wage1 = wagecat[_n-1]
keep wagecat wage1
save lagwage, replace

use http://www.stata-press.com/data/r8/womenwage, clear
merge wagecat using lagwage

generate wage2 = wagecat
replace wage2 = . if wagecat == 51
sort age, stable
list wage1 wage2 in 1/10

intreg wage1 wage2 age age2 nev_mar rural school tenure, nolog

oprobit wage1 wage2 age age2 nev_mar rural school tenure, nolog


*** Panel RE INTREG (xtintreg)

use http://www.stata-press.com/data/r8/nlswork3.dta, replace

xtintreg ln_wage1 ln_wage2 union age grade not_smsa south southXt occ_code, i(id) noskip intreg nolog
*quadchk


*** Truncated Regression

use http://www.stata-press.com/data/r8/laborsub, replace

truncreg whrs kl6 k618 wa we, ll(0) nolog
tobit whrs kl6 k618 wa we, ll(0) nolog